Kết nối PIC với EEPROM, DS1307 dùng chuẩn I2C ( hardware)

******************
Part1: Giới thiệu

Đã làm việc với VĐK và cụ thể là PIC chúng ta không thể không biết đến chuẩn I2C, đã có rất nhiểu bài viết nói vè cái này, nhưng một cách chi tiết cụ thể mình chưa thấy. Nhân ngày chủ nhật rỗi rãi xin trình bày với các bạn về chuẩn I2C

I2C: Viết tắt của Inter-Intergrated Circuit – là một bus nối tiếp do Philip phát triển. Trước đây I2C chủ yếu được dùng trong việc chế tạo các hệ thống điện tử sử dụng chip của Philip. Ngày nay I2C được sử dụng rộng rãi trong việc kết nối các thiết bị ngoại vi tốc độ thấp vào các mạch tích hợp. I2C sử dụng 2 đường truyền tín hiệu 2 chiều (một đường clock và một đường data), sử dụng hiệu điện thế 5V và cùng được kéo lên cao(pull-ups) bằng điện trở. I2C hoạt động theo nhiều mode: mode chuẩn (standard mode) hoạt động ở tốc độ 100kbit/s, mode tốc độ thấp (low-speed mode) hoạt động ở tốc độ 10kbit/s. Tần số clock có thể cho xuống 0. I2C có sử dụng 7 bit để định địa chỉ, do đó trên một bus có thể có 112 nút (16 địa chỉ được sử dụng vào mục đích riêng). Điểm mạnh của I2C là ở chỗ, một vi điều khiển có thể dùng để điều khiển cả một mạng thiết bị mà chỉ tốn 2 chân của vi điều khiển.

Chính vì nguyên nhân đó mà I2C cùng với SPI là hai chuẩn giao tiếp được sử dụng nhiều nhất trong các IC đặc biệt là các VĐK 8 bít.


Part2: I2C trong VĐK PIC

Ở Việt Nam Pic16x được sử dụng và đề cập nhiều nhất là 16F84, 16F628, 16F88, 16F87x. Trong đó:

+ 16F84, 16F628 ko tích hợp chuẩn I2C
+ 16F88 tích hợp I2C nhưng chỉ hỗ trợ chế độ Slave, ko dùng đựoc chế độ Master
+ 16F87x tích hợp I2C cả chế độ Master và Slave

Do đó nếu muốn sử dụng chế độ Master với các chíp 16F84, 16F628, 16F88 chúng ta phải gây dựng bằng phần mềm, và đã có rất nhiều tài liệu đề cập đến cái này điển hình nhất là Tutorial6 của ngài Nigel, các bạn hoàn toàn có thể tham khảo, hay copy paste code về I2C vào trong chương trình của mình, ( cũng ko nên tự gây dựng nấy vì nếu tự làm sẽ mất rất nhiều thời gian, và ko tối ưu )

Còn với 16F87x để sử dụng chuẩn giao tiếp I2C ta có thể dùng Hardware đã được tích hợp sẵn. Cái này dùng đơn giản hơn, code ngắn hơn và tối ưu hơn so với việc sử dụng Software. Do đó trong Project này tôi chỉ xin đề cập đến việc dùng I2C trong 16F87x


Part3: Cách sử dụng I2C chế độ Master trong 16F87x

Trong Pic 16F87x có 3 thanh ghi điều khiẻn quá trình truyền và nhận dữ liệu: đó là SSPSTAT ( 94h bank 1), SSPCON1 ( 14H bank 0) và SSPCON2 ( 91H bank 1 ). Trong đó thì:

SSPSTAT:
+ SMP chọn Speed chuẩn ( =1: 100Kb, 1Mb, =0: 400Kb)
+ CKE
+ R/W báo rằng quá trình truyền vẫn đang diễn ra
+ BF báo rằng SSPBUF vẫn đang đầy ( trong cả hai trường hợp transmit, Receive )



SSPCON1
+ WCOL : báo rằng có sự xếp chông dữ liệu
+ SSPEN enable chế độ I2C
+ SSPM3:SSPM0: chọn chế độ với chế độ I2C master: là '1000'



SSPCON2
+ ACKSTAT: Bít ACK được nhận từ Slave ( =0, chỉ dùng trong Transmit )
+ ACKDT, ACKEN: dùng để phát bít ACK hay NACK từ Master ( trong chế độ Receive ACKDT =0 là ACK, =1 là NACK )
+ RCEN : tín hiêu báo hiệu quá trình nhân ( chỉ dùng trong Receive: khi RCEN = 1, Master nhận tín hiệu từ Slave )
+ PEN, RSEN, SEN: bit khởi tạo quá trình truyền Stop, Restart, Start



Để điều khiển tốc độ baud của chế độ, người ta sử dụng thanh ghi SSPADD.
I2C làm việc ở 3 chế độ chuẩn ( tất nhiên chỉ tương đối ) : 100Kb, 400Kb, 1Mb. Nếu ta dùng thạch anh 4M, và cần sử dụng tốc độ 100Kb ta phải nạp giá trì vào thanh ghi SSPADD là: 28H với tốc độ 400Kb ta cần giá trị là 0AH. ( Tham khảo trang 97 Table 9-17( datasheet ) để biết thêm chi tiết )

Còn để lưu và nhận dữ liệu người ta dùng thanh ghi SSPBUF

Như vây tổng cộng có cả thẩy 5 thanh ghi được dùng đến : SSPSTAT, SSPCON1, SSPCON2 ( chọn chế độ và đỉều khiển đường truyền ) SSPADD ( khởi tạo tốc độ Baud ) và SSPBUF dùng để lưu dữ liệu trong hai quá trình Receive, và Transmister.

1. Hàm Initialize của I2C
Cũng tương tự như khi dùng USART, LCD, PWM... đầu tiên ta phải khởi tạo các giá trị ban đầu của chúng. Chúng ta nên tách riêng việc khởi tạo này thành một chương trình con. Việc khởi tạo phải theo các bước như sau:
+ Chọn chế độ Master mode bằng việc SSPM3 : SSPM0 = 1000
+ Enable MASTER mode: SSPEN = 1
+ Chọn baud chuẩn với 100Kb thì SMP =1
+ Set tốc độ baud của đường truyền: với 100Kb thì SSPADD = 28H
Dưới đây là chương trình cho Initialize cho I2C:

INIT_I2C
Code:

Code:

INIT_I2C
     
        BANKSEL SSPCON            ; chon MSSP che do MASTER MODE
        MOVLW  B'00101000'      ; Thiet lap MSSP cho chan PORTC o che do I2C
        MOVWF  SSPCON            ; SSPEN, SSPM BITS

        BANKSEL SSPSTAT        ; Thiet lap che do chuan cua toc do baud ( SMP= 1 ) 
        MOVLW  B'10000000'      ; Toc do chuan la 100Kb
        MOVWF  SSPSTAT   

        BANKSEL SSPADD            ; Thiet lap toc do duong truyen
        MOVLW  0x28                  ; Tinh toan gia tri cho thiet lap toc do
        MOVWF  SSPADD
       
        RETLW  0x00 

2. Truyền các bít chức năng
Để truyền và nhận dữ trong I2C tạo thành khối người ta dùng các bít Stop, Start, Restart, ACK, NACK ( ứng với PEN, SEN, RSEN, ACKEN, ACKDT ), Ý nghĩa của các bít này các bạn tham khảo các tài liệu nói về chuẩn I2C, tôi sẽ ko đề cập ở đây ( vì nói cái này sẽ rất dài dòng ) mà ở đây tôi chỉ đề cập đến hoạt dộng của các bít này trong PIC16F87x
(http://users.pandora.be/educypedia/electronics/I2C.htm I2C chuẩn tham khảo tại đây )

Quá trình hoạt động các bit này khá giống nhau đẻ bắt đầu phát đi: ta phải set bit tưong ứng trong thanh ghi đó đi VD muốn gửi bít Stop đi ta chỉ cần PEN =1, tưong tự với các bit kia và khi đã truyền xong rồi thì các bit đó sẽ tự động chuyển về 0 ( băng Hardware) .

Nhưng các bạn phải lưu ý qúa trình hoạt động này chỉ có tác dụng khi mà I2C đã hoàn thành xong nhiệm vụ trước đó. Như vậy ta cần phải biết được lúc nào chương trình đa hoàn thành xong nhiệm vụ và đây chính là vai trò của cờ SSPIF trong thanh ghi PIR1. Cũng tương tự như các cơ khác, SSPIF báo cho uC biét là hoạt động đã kết thúc bằng cách Set từ 0 lên 1 và ta phải xoá cờ này băng phần mềm cho các hoạt động tiếp theo. Do yêu cầu I2C là: khi hoạt động này kết thúc, thì mới cho phép hoạt động kia bắt đầu chính yêu cầu này đặt ra chúng ta phải có một chương trình con báo hiệu khi kết thúc một hoạt động. Như vậy chương trình con đó là:

WaitMSSP
Code:

Code:

WaitMSSP
        BANKSEL PIR1
        BTFSS  PIR1,SSPIF        ; Kiem tra trang thai co
        GOTO    $-1                      ; Chua hoan thanh
        BCF    PIR1,SSPIF          ; Da hoan thanh cong viec, luc nay co the chuyen sang hoat dong moi
        RETLW  0 

Chương trình con này sẽ được dùng rất nhiều về sau trong mọi hoạt động của chương trình, và ta nên đặt chương trình con này ở cuối các hoạt động

Như vậy kết hợp với chương trình con WaitMSSP chúng ta có các hoạt động: phát ra bit Stop, Restart.... là

STARTBit
Code:

Code:

STARTBit
        BANKSEL SSPCON2
        BSF    SSPCON2,SEN      ; Gui bit start 
        CALL    WaitMSSP   
        RETLW  0x00

RESTARTBit
Code:

Code:

RESTARTBit
        BANKSEL SSPCON2
        BSF    SSPCON2,RSEN      ; Gui bit restart 
        CALL    WaitMSSP   
        RETLW  0x00

STOPBit
Code:

Code:

STOPBit
        BANKSEL SSPCON2          ; Gui va kiem tra bit Stop, doi cho den khi hoan thanh xong
        BSF    SSPCON2,PEN      ; gui bit Stop
        CALL    WaitMSSP
        RETLW  0x00

ACKBit
Code:

Code:

ACKBit
        BANKSEL SSPCON2
        BCF    SSPCON2,ACKDT    ; Chon gui ACK
        BSF    SSPCON2,ACKEN    ; Gui
        CALL    WaitMSSP
        RETLW  0x00

NACKBit
Code:

Code:

NACKBit
        BANKSEL SSPCON2
        BSF    SSPCON2,ACKDT    ; Chon gui NACK
        BSF    SSPCON2,ACKEN    ; Gui di
        CALL    WaitMSSP
        RETLW  0x00

( Lưu ý có sự khác biệt một chút trong bit ACKBit, NACKBit là : ACKEN gửi bit ACK nói chung đi, còn ACKDT dùng để chọn bit gửi đi là ACK ( = 0 ) hay NACK ( =1 ) )

3. Truyền và nhận dữ liệu trong I2C
Bước tiếp theo tôi xin đề cập đến cách truyền và nhận dữ liệu trong PIC16F87x.

Các bạn phải phân biệt được cách chuyền và nhận ( tưong ứng với Transmit, Receive ) trong PIC

Để bắt đầu nhận dữ liệu từ Slave thì Master phải set bít RCEN = 1 , cũng tương tự như các bít Stop, Start,..... đây cũng là một hoạt động, sau khi bit cuối cùng đuợc nhận thì RCEN sẽ tự động Clear, do đó để bắt đầu quá trình Read tiếp theo thì ta phải tiép tục Set RCEN ( đối với quá tình đọc ít nhất hai lần trở lên ) đê tiếp tục một hoạt động mới. Ta có module nhận dữ liệu

READ_I2C
Code:

Code:

READ_I2C                          ;  Bit gui la cuoi la ACK
        BSF    STATUS,RP0
        BTFSC  SSPSTAT,2            ; kiem tra bit R/W, xem qua trinh Transmit da ket thuc chua
        GOTO    $-1
        BANKSEL SSPCON2
        BSF    SSPCON2,RCEN      ; cho phep RECEIVE Mode (I2C )
        CALL    WaitMSSP              ; Doi cho den khi I2C thuc hien xong TUC LA NHAN DU LIEU XONG
        CALL    ACKBit                    ; Gui bit ACK toi Slave
        BANKSEL SSPBUF 
        MOVF    SSPBUF,W          ; Luu du lieu vao W
        RETURN

Trong module này tôi có dùng bít R/W ở thanh ghi SSPSTAT, bít này cho sự đảm bảo rằng quá trình Transmit đã kết thúc và sẵn sàng cho hoạt động Receive, Khi qua trình truyền kết thúc ta gửi bit ACK tới Slave báo cho Slave biết rằng Master sẵn sàng nhận dự liệu tiếp theo


Còn quá trình truyền dữ liệu là ngay sau khi chúng ta ghi dữ liệu cần truyền lên thanh ghi SSPBUF tất nhiên, quá trình Transmit bắt đầu ( lúc bắt đầu ghi dữ liệu lên SSPBUF ) khi các hoạt động trước nó đã kết thúc. Vậy ta có module truyền là

WRITE_I2C
Code:

Code:

WRITE_I2C                                ; In la W
        BANKSEL SSPBUF            ; Chon bank0
        MOVWF  SSPBUF            ; 
        CALL    WaitMSSP
        RETLW  0x00

Tài liệu về I2C tham khảo ở :http://ww1.microchip.com/downloads/en/DeviceDoc/i2c.pdf

Và đến đây chúng ta đã có đủ các công cụ cho việc tryền hay nhận dữ liệu dùng I2C rôi đấy


Part 4. Truyền và nhận dữ liêu qua EEPROM 24C01C

1.) Quá trình truyền một byte dữ liệu từ Master qua slave ( transmit )
Nguyên tắc truyền một byte dữ liệu gồm có các bước cơ bản sau ( tôi ko muốn đề cập đến việc dùng ngắt để xử lý vì rất phức tạp )
+ Gửi bít Start từ Master tới slave. Đợi cho đến khi truyền xong
+ Gửi địa chỉ của slave lên đường truyền. Dùng để chọn Slave nào hoạt động, Đợi cho đến khi truyền xong
+ Gửi địa chỉ cần lưu dữ liệu tới . Đợi cho đên khi truyền xong
+ Gửi dữ liệu cần truyền tới Slave, đợi cho đến khi truyền xong
+ Tiếp tục gửii dữ liệu ......
+ Khi muốn kết thúc gửi bít Stop lên đường truyền

Tuân thủ lần lượt các bước trên ta có module truyền dữ liệu của một byte

WRITE_BYTE
Code:

Code:

WRITE_BYTE                              ; IN ACC: dulieu, ADDR dia chi can truy nhap
        CALL    STARTBit

        MOVLW  ADDR_RTC          ; Load CONTROL BYTE (input mode)
        CALL    WRITE_I2C

        MOVF    ADDRESS,W          ; Xuat du lieu ra I2C
        CALL    WRITE_I2C

        MOVF    ACC,W                    ; Xuat du lieu ra I2C
        CALL    WRITE_I2C
 
        CALL    STOPBit
        RETLW  0x00                      ; Ket thuc qua trinh viet du lieu len EEPROM

Lưu ý : ADDR_RTC là địa chỉ của Slave và bit 0 của nó phải bằng 0 ( báo cho Slave biết quá trình là Write ) còn ACC là biến dữ liệu, ADDRESS là biến đia chỉ ta cần dưa vào
Như vậy để truyền một byte dữ liệu là 0x15 có địa chỉ 0x05 tới EEPROM 24C01C ( địa chỉ 0xA0 ) ta chỉ việc:

ADDR_RTC EQU 0xA0 ; Dia chi
ADDRESS EQU 0x20 ; Khai bao Ram
ACC EQU 0x21
.............................

MOVLW 0x06
MOVWF ADDRESS
MOVLW 0x15
MOVWF ACC
CALL WRITE_BYTE

2. Quá trình nhận dữ liệu từ slave
Quá trình nhận dữ liệu từ slave phải tuân thủ theo các bước sau
+ Gửi bít Start từ Master tới slave. Đợi cho đến khi truyền xong
+ Gửi địa chỉ của slave( bit 0 = 0 ) lên đường truyền. Dùng để chọn Slave nào hoạt động, Đợi cho đến khi truyền xong
+ Gửi địa chỉ của dữ liệu càn nhận Đợi cho đên khi truyền xong
+ Gửi bit Restart, Đợi cho đến khi truyền xong
+ Gửi địa chỉ của slave lên đường truyền ( bit 0 =1 báo rằng hoạt động sắp tới là đọc). Đợi cho đến khi truyền xong
+ Đọc dữ liệu từ Slave . Đợi cho đên khi đọc xong
+ Phát bít ACK báo tiếp tục nhận dữ liệu . Đợi cho đên khi truyền xong
+ Đọc dữ liệu từ Slave . Đợi cho đên khi đọc xong
+ Phát bít ACK báo tiếp tục nhận dữ liệu . Đợi cho đên khi truyền xong
...................
+ Đọc dữ liệu từ Slave . Đợi cho đên khi đọc xong
+ Phát bít NACK báo rằng qua trình nhận dữ liệu đã kết thúc . Đợi cho đên khi truyền xong
+ Phát bít Stop để kết thúc

Tuân thủ theo các bước trên ta sẽ có quá trình đọc một byte dữ liệu

READ_BYTE
Code:

Code:

        MOVF    ADDRESS,W        ; Load ADDRESS Byte vao W
        CALL    WRITE_I2C
   
        CALL    STOPBit                ; Qua trinh restart
        CALL    STARTBit
       
        MOVLW  AĐR_RTC
        ADDLW    0x01                  ; Set bit 0 = 1 bao cho slave biet qua trinh doc lan sau
        CALL    WRITE_I2C
 
        BSF    STATUS,RP0
        BTFSC  SSPSTAT,2        ; kiem tra bit R/W
        GOTO    $-1

        BANKSEL SSPCON2
        BSF    SSPCON2,RCEN      ; Cho phep RECEIVE Mode (I2C )          ; loi o cho nay day
        CALL    WaitMSSP

        BCF    STATUS,RP0
        BCF    PIR1,SSPIF
       
        CALL    NACKBit          ; Phat bit NACKBit ket thuc qua trinh nhan
       
        CALL    STOPBit

        BANKSEL SSPBUF            ; 
        MOVF    SSPBUF,W          ; Luu gia tri doc duoc tu EEPROM vao thanh ghi W

        RETURN                    ; Ket thuc qua trinh doc ghi

Như vây để đọc giá tri tại địa chỉ 0x05 của EEPROM 24C01C và lưu dũ liệu vào thanh ghi ACC ta làm như sau

MOVLW 0x05
MOVWF ADDRESS
CALL READ_BYTE
MOVWF ACC

Thật đơn giản phải ko nào. Bây gờ các bạn có thể hoàn toàn tự truy suất EEPROM một cách vô tư, tuỳ ý rồi đây


Part 5 Giao tiếp với DS1307 real time clock dùng PIC16F877A

DS1307 là con Real Time clock của hãng Dallas và đựoc dùng khá phổ biến hiện nay. Cũng giống như các RTC khác, DS1307 có các đặc tính sau:

+ Dùng chuẩn giao tiếp I2C
+ Hiển thị giờ phút giây, ngày, tháng năm ( đến tận năm 2099 )
+ Dùng thạch anh 32.768 Khz làm bộ tạo dao động
+ Sử dụng Pin 3V đề đề phòng khi mất điện
+ Có 56 byte Ram cho người sử dụng......

Một số đặc điểm mà các bạn cần phải chú ý:

+ DS1307 có 7 byte dữ liệu nằm từ địa chỉ 0x00 tới 0x06, 1 byte điểu khiển, và 56 byte lưu trữ ( dành cho người sủ dụng )
+ Khi xử lý dữ liệu từ DS1307, họ đã tự chuyển cho ta về dạng số BCD, ví dụ như ta đọc đựoc dữ liệu từ địa chỉ 0x04 ( tưong ứng với Day- ngày trong tháng) và tại 0x05 ( thang ) là 0x15, 0x11 như thế có nghĩa là lúc đó là ngày 15-11 chứ ko phải là ngày 21 tháng 17
+ Lưu ý đến vai trò của chân SQW/OUT. Đây là chân cho xung ra của DS1307 có 4 chế độ 1Hz, 4.096HZ, 8.192Hz, 32.768Hz... các chế độ này đuợc quy định bởi các bít của thanh ghi Control Register ( địa chỉ 0x07 )
+ Địa chỉ của DS1307là 0xD0

Quay lại với phần trên có lẽ có nhiều bạn thắc mắc tại sao chúng ta có thể đọc ghi một cách liên tục và địa chỉ sẽ như thế nào. Thật đơn giản địa chỉ truy suất phụ thuộc vào dịa chỉ ban đầu mà ta đưa vào, và sau mỗi lần đọc/ghi dữ liệu, biến địa chỉ này tự động tăng lên một cho đến khi gặp bit Stop thì thôi

Trở lại với Project của chúng ta biến chúng ta cần truy suất ở đây cả thảy có 7 địa chỉ đó là Second, minute, hour, Day, Date, Month, year vây ta cần phải đặt 7 biếnt dữ liệu trong chương trình trong việc xử lý dữ liệu. Sau đây là đặt biền và chương trình con để đọc dữ liệu từ RTC

Code:

Code:


        CBLOCK    0x20            ;start of general purpose registers
            ADDRESS
            ACC
            RAM_SEC     
            RAM_MIN       
            RAM_HOU       
            RAM_DAY       
            RAM_DAT       
            RAM_MON       
            RAM_YEA       
    endc

;.................................
main:

;.................................
READ_RTC                         
        CALL    STARTBit          ; Gui bit Start

        MOVLW  ADDR_RTC          ; Load CONTROL BYTE  ( cho viec xuat du lieu )
        CALL    WRITE_I2C

        MOVLW  0x00              ; Load ADDRESS Byte vao W
        CALL    WRITE_I2C
 
        CALL    STOPBit
        CALL    STARTBit

        MOVLW  0xD1          ; Chon che do dia chi read
        CALL    WRITE_I2C     

; Qua trinh doc du lieu tu RTC
        CALL    READ_I2C          ; Doc du lieu SECOND
        MOVWF  RAM_SEC
        CALL    READ_I2C          ; Doc du lieu MINUTE
        MOVWF  RAM_MIN
        CALL    READ_I2C          ; Doc du lieu HOUR
        MOVWF  RAM_HOU   
        CALL    READ_I2C          ; Doc du lieu DAY
        MOVWF  RAM_DAY
        CALL    READ_I2C          ; Doc du lieu DATE
        MOVWF  RAM_DAT
        CALL    READ_I2C          ; Doc du lieu MON
        MOVWF  RAM_MON
        BSF    STATUS,RP0
        BTFSC  SSPSTAT,2        ; kiem tra bit R/W
        GOTO    $-1
        BSF    SSPCON2,RCEN      ; Cho phep RECEIVE Mode (I2C )
        CALL    WaitMSSP          ; Doi cho den khi I2C thuc hien xong TUC LA NHAN DU LIEU XONG
        CALL    NACKBit          ; Bao cho SLAVE ket thuc qua trinh nhap du lieu
        BANKSEL SSPBUF
        MOVF    SSPBUF,W
        MOVWF  RAM_YEA          ; Doc du lieu year ( du lieu cuoi cung )
        CALL    STOPBit
        RETLW  0x00              ; Ket thuc qua trinh doc ghi

Với chương trình đọc dữ liệu trên ta hoàn toàn có thể truy suất vào RTC bất cứ lúc nào để biết giờ hệ thống. Nhưng ở đây lại có một bài toán đặt ra là nên chọn thời điểm nào để đọc hay đọc như thế nào. Những bạn nào đã từng làm về RTC chăc hẳn đã gặp phải trường hợp là kim giây nhảy lung tung lên, tôi nghĩ rằng nguyên nhân ở chỗ các bạn đọc dữ liệu một cách liên tục. Rõ ràng cách này là hoàn toàn ko tối ưu. Giải pháp như thế nào cho hợp lý

Các bạn có thấy vai trò của chân SQW ở trên ko, nó co một chế độ phát xung 1Hz như vậy nếu như ta nối chân này với một trở 4,7K kéo lên nguồn và mắc vào chân RB0 của PIC16F877, và cho sử dụng ngắt ngoài Như vậy cứ mỗi khi có ngắt thì ta mới tiến hành đọc dũ liệu. Tôi nghĩ cách này rất tối ưu, vì trong thời gian chờ đợi ta có thể làm việc khác chứ ko phải là chỉ có việc đọc dữ liệu từ RTC. Như vậy chương trình ngắt sẽ là

movwf w_temp ; save off current W register contents
movf STATUS,w ; move status register into W register
movwf status_temp ; save off contents of STATUS register
movf PCLATH,w ; move pclath register into w register
movwf pclath_temp ; save off contents of PCLATH register

;************************************************* *****************************
;
BTFSS INTCON,1
GOTO NEXT_INTERUPT
BANKSEL PORTB
CALL READ_RTC
; Qua trinh xu ly du lieu va xuat du lieu tai day
BCF INTCON,1
NEXT_INTERUPT
;************************************************* *****************************

movf pclath_temp,w ; retrieve copy of PCLATH register
movwf PCLATH ; restore pre-isr PCLATH register contents
movf status_temp,w ; retrieve copy of STATUS register
movwf STATUS ; restore pre-isr STATUS register contents
swapf w_temp,f
swapf w_temp,w ; restore pre-isr W register contents
retfie ; return from interrupt


Việc xử lý dữ liệu và truy suất dữ liệu bằng Led 7 đoạn, hay bằng LCD như thế nào là tuỳ thuộc ở các bạn....

Xem thêm tại:
[You must be registered and logged in to see this link.]

Thích Tiếng Anh thì đọc tại đây:
[You must be registered and logged in to see this link.]